1

Closed

SQL Azure incompatibility issue

description

SQL Azure does not support FullText Search, and the version "Active Forums 05.00.04 for DNN 7 - BETA 4" has an incompatibility on the stored procedure [dnn_activeforums_Search_GetFullTextStatus]. A compatible script with both SQL Azure and onpremise install would be:

ALTER PROCEDURE [dbo].[dnn_activeforums_Search_GetFullTextStatus]

AS

BEGIN
DECLARE @ProductEdition INT
SET @ProductEdition = CAST(ServerProperty('EngineEdition') as INT)

IF (@ProductEdition = 5) --Check for SQL Azure
BEGIN
        SELECT 0 as Status 
        RETURN
END
ELSE
BEGIN    

EXEC ('
    IF FullTextServiceProperty(''IsFullTextInstalled'') < 1
    BEGIN
        SELECT 0 as Status
        RETURN
    END

    DECLARE @dbName nvarchar(1000)
    SET @dbName = DB_NAME()

    IF DATABASEPROPERTY(@dbName, ''IsFulltextEnabled'') = 0
    BEGIN
        SELECT -1 as Status
        RETURN
    END

    IF OBJECTPROPERTY(object_id(''dbo.dnn_activeforums_Content''),''TableHasActiveFulltextIndex'') = 0
    BEGIN
        SELECT -2 as Status
        RETURN
    END

    IF NOT EXISTS (SELECT * FROM sys.objects where object_id = object_id(N''dbo.dnn_activeforums_Search_FullText'') and OBJECTPROPERTY(object_id, N''IsProcedure'') = 1)
    BEGIN
        SELECT -3 as Status
        RETURN
    END

    SELECT 1 as Status
    RETURN')
END

END

GO
Closed Nov 25, 2013 at 5:12 PM by jbrunken
Fixed in 5.0.5+

comments

jbrunken wrote Nov 25, 2013 at 5:12 PM

This was a known issue that has been addressed in the latest release candidates.